# Maintainer:  Holo Team
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinxu.org>
# Contributor: Wael Nasreddine <gandalf@siemens-mobiles.org>
# Contributor: Tor Krill <tor@krill.nu>
# Contributor: Will Rea <sillywilly@gmail.com>
# Contributor: Valentine Sinitsyn <e_val@inbox.ru>

# Holo: Include the 802.1X patch, until it can either be dropped or merged upstream
# Holo: Include fix to allow NM to take over the autoconnect duty. Still TBD if this
#       is a proper fix that can be sent upstream

pkgbase=networkmanager
pkgname=(
  networkmanager
  libnm
  nm-cloud-setup
  networkmanager-docs
)
pkgver=1.58.0
pkgrel=1.9
pkgdesc="Network connection manager and user applications"
url="https://networkmanager.dev/"
arch=(x86_64)
license=(LGPL-2.1-or-later)
makedepends=(
  audit
  bash
  bpf
  clang
  curl
  dhcpcd
  dnsmasq
  git
  glib2
  glib2-devel
  glibc
  gobject-introspection
  gtk-doc
  iproute2
  iptables
  iwd
  jansson
  libbpf
  libgcc
  libmm-glib
  libndp
  libnewt
  libnvme
  libpsl
  libteam
  meson
  modemmanager
  nftables
  nspr
  nss
  openresolv
  pacrunner
  perl-yaml
  polkit
  ppp
  'python>=3.14'
  'python<3.15'
  python-gobject
  readline
  slang
  systemd
  systemd-libs
  vala
  wpa_supplicant
)
checkdepends=(
  libx11
  python-dbus
)
source=(
  "git+https://gitlab.freedesktop.org/NetworkManager/NetworkManager.git#tag=${pkgver/[a-z]/-&}"
  # Holo: https://gitlab.steamos.cloud/jupiter/tasks/-/issues/520
  # https://gitlab.freedesktop.org/NetworkManager/NetworkManager/-/merge_requests/1264
  "0002-iwd-remove-8021X-unknown-network-restrictions.patch"
  # Holo: part of https://gitlab.steamos.cloud/deckard/tasks/-/work_items/725
  # At the moment of writing this patch has not been sent upstream yet
  # TBD if it should be reworked or if it's fine to send as-is
  "0001-iwd-take-over-scanning-and-autoconnect-when-IWD-auto.patch"
  # Holo: part of https://gitlab.steamos.cloud/holo-team/tasks/-/work_items/1471
  # This patch is backported from upstream and will be available in 1.59.0
  # https://gitlab.freedesktop.org/NetworkManager/NetworkManager/-/commit/6b56139c
  "0001-libnm-core-allow-connecting-to-SAE-networks-with-key.patch"

  # Holo: https://gitlab.steamos.cloud/holo-team/tasks/-/work_items/1457
  # https://gitlab.freedesktop.org/NetworkManager/NetworkManager/-/merge_requests/2514
  "0001-wifi-supplicant-scan-only-the-last-associated-freq.patch"

  # Holo: https://gitlab.steamos.cloud/holo-team/tasks/-/work_items/1471
  # Workaround needed for 3.9. Can be dropped in 3.10 once 3.9 reaches
  # stable and users can no longer downgrade to 3.8 from the UI.
  "0001-iwd-mirror-wpa_supplicant-connections-into-IWD-profi.patch"
  "0002-iwd-remove-IWD-profile-on-forget.patch"

  # Holo: https://gitlab.steamos.cloud/holo-team/tasks/-/work_items/2308
  # At the moment of writing this patch has not been sent upstream yet
  "0001-wifi-iwd-fix-forget-connect-issue.patch"

  # Holo: https://gitlab.steamos.cloud/holo-team/tasks/-/work_items/523
  # https://gitlab.freedesktop.org/NetworkManager/NetworkManager/-/merge_requests/2455
  "0001-wifi-iwd-retry-hidden-network-activation.patch"

  # Holo: https://gitlab.steamos.cloud/holo-team/tasks/-/work_items/1457
  # iwd: check for sae network type
  # At the moment of writing this patch has not been sent upstream yet
  "0001-iwd-check-for-sae-network-type.patch"
)
b2sums=('1bf42970ab8ffc3fe919d00cf2aca9626dfde0db24e655514b4f2873fef2dda3a88608d72487619c755f5c9e366789cf18943e7502a3ec5476ea7c914d7d48a4'
        'acb84792effee07ff8853f85136d5fe2822f11810a82a6dbb071c9dba7051d9f5ad232e49442b78cf3b29f24caf9e947ee18941adbe3e1876c11f7212e055509'
        '4e9d904527b8c7f85c68119c75cc92afba70948a188fa3c679e339171f68cf8da075ad4fcf04d1ed8ee11f4a2164c84010e1338552601d4a0a93da8a8ea1d662'
        '89e643e4e708b837fc666cf17bac26677568ca2ed7e5a14b4f18772a5b233591452cc95b32d00dd875bad8a8d9a16b0decdb60279efc36c9a71547b2680a17e1'
        '83fa2db6a72c30a9ee636929d967fff75bccb2612d9ace5e3eed5b0917793e561aed244ebf62ebb51c2155567f0057bdcf41c717b5b1beaae05543b318fa705c'
        'a700bf7a441b2dcc5aca0847936d890e07b9297970592945732107f90fdf6d0f7dc500f850aaf36d4af77c384905112543d267d3f3ba2214622f2da33f78fae4'
        '97a27192ccc2cf37a7cc7cdccc4b867c127bcb2a698db1b4c529c3021e01ea5b6a61738f50f6c7c04acb6f72995583ecf1d0e6896b15b5cb7eee5f0cf404ed05'
        'e5b1a720ed6111f4a7f8f041ce9b6fbd288c025605a1d34ab66bdf421d554ccb7d40e97e6e307b2f7634f6ef5a0f31da3fd8637b4b31b1a2ff9cee6f132839f8'
        '634f6aa94a9692134006c0085f7a67c54c9d6d9fac158d601bca1e454eebce14fb99652d0db946283cd2230c4ae509b541c603348f7ba7b63b1e413245b268ac'
        '94c62866bf2783a9acfa3507f45e7e7b3229fcb32fcd5d917538379f74ada851fb2a0be4028b96fe638df2e85afd1b1253dd4e3ed8a5e7fc98ebbaa56fe32310')
validpgpkeys=(
  3D10AD045AB4AAFF8E8F36AF9B980AC2FB874FEB # Ana Cabral <acabral@redhat.com>
  F07F7C1EABD382F81CBFBA3B998D4828CD7E1656 # Beniamino Galvani <bgalvani@redhat.com>
  2B5F3B2028801E15F57AAA309906C97AA15D984F # Fernando Fernandez Mancera <ffmancera@riseup.net>
  48FD6FAE515A77B48436821C8789567B8715CEBC # Gris Ge <fge@redhat.com>
  ACFA41513D2854D0A72F55BE9A2C77A85F2D72FE # Ján Václav <jvaclav@redhat.com>
  4B8EF9745A973724E965939189A2DA5AF73D5E3D # Lubomir Rintel <lkundrak@v3.sk>
  E472337703D0C46002928B5790617850A125DE59 # Stanislas FAYE <sfaye@redhat.com>
  49EA7C670E0850E7419514F629C2366E4DFC5728 # Thomas Haller <thaller@redhat.com>
  07F9AEC86144386D9576210B66A44781B4EBC2D0 # Íñigo Huguet <ihuguet@redhat.com>
  8D1F4C471D38D59A56301CEBE1974C8D8DD6ED2A # Filip Pokryvka <fpokryvk@redhat.com>
  1CFF865BDF957BE935765BBD2E1878D078DEF7C6 # Íñigo Huguet <ihuguet@riseup.net>
  8353041CB75BD30380E0C97CBB71790DF5ADC65C # Vladimír Beneš <vbenes@redhat.com>
  100A50E46DC2C244F838DCBFABD48F465F4434BD # Josephine Pfeiffer <josie@redhat.com>
)

prepare() {
  cd NetworkManager

  # Holo
  patch -Np1 < ../0002-iwd-remove-8021X-unknown-network-restrictions.patch
  patch -Np1 < ../0001-iwd-take-over-scanning-and-autoconnect-when-IWD-auto.patch
  patch -Np1 < ../0001-libnm-core-allow-connecting-to-SAE-networks-with-key.patch
  patch -Np1 < ../0001-wifi-supplicant-scan-only-the-last-associated-freq.patch
  patch -Np1 < ../0001-iwd-mirror-wpa_supplicant-connections-into-IWD-profi.patch
  patch -Np1 < ../0002-iwd-remove-IWD-profile-on-forget.patch
  patch -Np1 < ../0001-wifi-iwd-fix-forget-connect-issue.patch
  patch -Np1 < ../0001-wifi-iwd-retry-hidden-network-activation.patch
  patch -Np1 < ../0001-iwd-check-for-sae-network-type.patch
}

build() {
  local meson_options=(
    # build checks this option; injecting just via *FLAGS is broken
    -D b_lto=true

    # platform
    -D dist_version="$pkgver-$pkgrel"
    -D session_tracking_consolekit=false
    -D suspend_resume=systemd
    -D polkit_noauth_group=wheel
    -D selinux=false

    # features
    -D iwd=true
    -D teamdctl=true
    -D bpf-compiler=clang

    # configuration plugins
    -D config_plugins_default=keyfile
    -D ifupdown=false

    # handlers for resolv.conf
    -D netconfig=no
    -D config_dns_rc_manager_default=symlink

    # miscellaneous
    -D vapi=true
    -D docs=true
    -D more_asserts=no
    -D more_logging=false
    -D qt=false
  )

  arch-meson NetworkManager build "${meson_options[@]}"
  meson compile -C build
}

check() {
  NMTST_FORCE_REAL_ROOT=1 meson test -C build --print-errorlogs
}

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

package_networkmanager() {
  depends=(
    audit
    bash
    curl
    glib2
    glibc
    iproute2
    jansson
    libbpf
    libgcc
    libmm-glib
    libndp
    libnewt
    libnm
    libpsl
    libteam
    mobile-broadband-provider-info
    nspr
    nss
    readline
    slang
    systemd-libs
    wpa_supplicant
  )
  optdepends=(
    'bluez: Bluetooth support'
    'dhcpcd: alternative DHCP client'
    'dnsmasq: connection sharing'
    'firewalld: firewall support'
    'iptables: connection sharing'
    'iwd: wpa_supplicant alternative'
    'libnvme: NBFT support'
    'modemmanager: cellular network support'
    'nftables: connection sharing'
    'openresolv: alternative resolv.conf manager'
    'pacrunner: PAC proxy support'
    'polkit: let non-root users control networking'
    'ppp: dialup connection support'
  )
  backup=(etc/NetworkManager/NetworkManager.conf)

  # NM wants to move to LGPL only, but there's still GPL code left
  license+=(GPL-2.0-or-later)

  meson install -C build --destdir "$pkgdir"

  cd "$pkgdir"

  # /etc/NetworkManager
  install -d etc/NetworkManager/{conf,dnsmasq}.d
  install -dm700 etc/NetworkManager/system-connections
  install -m644 /dev/stdin etc/NetworkManager/NetworkManager.conf <<END
# Configuration file for NetworkManager.
# See "man 5 NetworkManager.conf" for details.
END

  # packaged configuration
  install -Dm644 /dev/stdin usr/lib/NetworkManager/conf.d/20-connectivity.conf <<END
[connectivity]
uri=http://ping.archlinux.org/nm-check.txt
END

  shopt -s globstar

  _pick docs usr/share/gtk-doc

  _pick libnm usr/include/libnm
  _pick libnm usr/lib/girepository-1.0/NM-*
  _pick libnm usr/lib/libnm.*
  _pick libnm usr/lib/nm-libnm-helper
  _pick libnm usr/lib/pkgconfig/libnm.pc
  _pick libnm usr/share/gir-1.0/NM-*
  _pick libnm usr/share/vala/vapi/libnm.*

  _pick cloud usr/lib/**/*nm-cloud-setup*
  _pick cloud usr/share/man/*/nm-cloud-setup*

  # Not actually packaged (https://bugs.archlinux.org/task/69138)
  _pick ovs usr/lib/systemd/system/NetworkManager.service.d/NetworkManager-ovs.conf

  # Restore empty dir
  install -d usr/lib/NetworkManager/dispatcher.d/no-wait.d
}

package_libnm() {
  pkgdesc="NetworkManager client library"
  depends=(
    glib2
    glibc
    libgcc
    nspr
    nss
    systemd-libs
    util-linux-libs
  )
  provides=(libnm.so)

  mv libnm/* "$pkgdir"
}

package_nm-cloud-setup() {
  pkgdesc="Automatically configure NetworkManager in cloud"
  depends=(
    bash
    curl
    glib2
    glibc
    jansson
    libgcc
    libnm
    networkmanager
  )

  mv cloud/* "$pkgdir"
}

package_networkmanager-docs() {
  pkgdesc+=" (API documentation)"
  depends=()

  mv docs/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et:
