# Maintainer: David Runge <dvzrv@archlinux.org>

_name=test-unit-ruby-core
pkgname=ruby-test-unit-ruby-core
pkgver=1.0.14
pkgrel=1
pkgdesc="Additional test assertions for Ruby standard libraries"
arch=(any)
url="https://github.com/ruby/test-unit-ruby-core"
license=(BSD-2-Clause Ruby)
depends=(ruby)
makedepends=(
  ruby-rake
  ruby-rdoc
)
source=($_name-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz)
sha512sums=('d71f2778e17ac0c3da8c2a31cbb2051dba9e109956888c94c83b62884479a01904dae0b44a1ba224f1b7e74fab38db974fca8674f107cacdb12d2b4238e834de')
b2sums=('bef8592d5f65cfc67f305139a4f6eba4a714217d01752a79961c7f30a519c5a1ce692d97ca740b32ad133d4a882ec9703b750011dbc93f07b2fb7ff396dec72c')

prepare() {
  cd $_name-$pkgver

  # update gemspec/Gemfile to allow newer version of the dependencies
  sed -i -e 's|~>|>=|g' $_name.gemspec
}

build() {
  local gemdir="$(gem env gemdir)"
  local gem_install_options=(
    --local
    --verbose
    --ignore-dependencies
    --no-user-install
    --install-dir tmp_install/$gemdir
    --bindir tmp_install/usr/bin
    $_name-$pkgver.gem
  )
  local unrepro_files=(
    tmp_install/$gemdir/cache/
    tmp_install/$gemdir/gems/$_name-$pkgver/vendor/
    tmp_install/$gemdir/doc/$_name-$pkgver/ri/ext/
  )

  cd $_name-$pkgver

  gem build $_name.gemspec
  gem install "${gem_install_options[@]}"

  # remove unrepreducible files
  rm -frv "${unrepro_files[@]}"

  find tmp_install/$gemdir/gems/ \
    -type f \
    \( \
      -iname "*.o" -o \
      -iname "*.c" -o \
      -iname "*.so" -o \
      -iname "*.time" -o \
      -iname "gem.build_complete" -o \
      -iname "Makefile" \
    \) \
    -delete

  find tmp_install/$gemdir/extensions/ \
    -type f \
    \( \
      -iname "mkmf.log" -o \
      -iname "gem_make.out" \
    \) \
    -delete
}

# NOTE: there is not test target

package() {
  cd $_name-$pkgver

  mv -v tmp_install/* "$pkgdir/"

  install -vDm 644 BSDL COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}
