# Maintainer: David Runge <dvzrv@archlinux.org>
# Maintainer: Christian Heusel <gromit@archlinux.org>

_name=pydantic-extra-types
pkgname=python-pydantic-extra-types
pkgver=2.11.0
pkgrel=1
pkgdesc="Extra pydantic types"
arch=(any)
url="https://github.com/pydantic/pydantic-extra-types"
license=(MIT)
depends=(
  python
  python-pydantic
  python-pydantic-core
)
makedepends=(
  python-build
  python-hatchling
  python-installer
)
checkdepends=(
  python-cron-converter
  python-dirty-equals
  python-pendulum
  python-phonenumbers
  python-pycountry
  python-pymongo
  python-pytest
  python-pytz
  python-semver
  python-ulid
)
optdepends=(
  'python-cron-converter: for cron support'
  'python-pendulum: for datetime support'
  'python-phonenumbers: for phone number support'
  'python-pycountry: for country code support'
  'python-pymongo: for MongoDB support'
  'python-pytz: for timezone support'
  'python-semver: for semantic versioning support'
  'python-tzdata: for timezone support'
  'python-ulid: for ULID support'
)
source=($_name-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz)
sha512sums=('4a16dc65ca9f5ab2f4458b7c800429e199b4504916008874aa5d7e1d13cb03fc571e5f8aa12ea6a8cdd4a1e2bd377261ff8219185d3f7307b3397c35e7cedc21')
b2sums=('b5b947a9ac9c957fc824a8528e2dadd3aebc6f7190e91f0a3d02c430ddab62396214c1f264d93c0c372acdbfef73fc117275406a3ce08aba08a81d1b5dc1c46d')

build() {
  cd $_name-$pkgver
  python -m build --wheel --no-isolation
}

check() {
  local pytest_options=(
    -vv
  )

  cd $_name-$pkgver
  export TZ=UTC
  pytest "${pytest_options[@]}"
}

package() {
  cd $_name-$pkgver
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}
