# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Carl Smedstad <carsme@archlinux.org>

pkgname=python-zope-deferredimport
_pkgname=zope.deferredimport
pkgver=6.0
pkgrel=2
pkgdesc="Allows you to perform imports names that will only be resolved when used in the code"
arch=('any')
url="https://github.com/zopefoundation/zope.deferredimport"
license=('ZPL-2.1')
depends=(
  'python'
  'python-zope-proxy'
)
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
  'python-wheel'
)
checkdepends=('python-zope-testrunner')
source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('13faabb126705dece0081d7f50a73f903bf5762b679db83f60dc21c881b24e1ce976664f9fc85fc3ac7d8cb75ea51c110edcdfecd6a00b8c652e5bbba41118e7')

build() {
  cd $_pkgname-$pkgver
  python -m build --wheel --no-isolation --skip-dependency-check
}

check() {
  cd $_pkgname-$pkgver
  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer dist/*.whl
  test-env/bin/python -m zope.testrunner -vc --test-path src/
}

package() {
  cd $_pkgname-$pkgver
  python -m installer --destdir="$pkgdir" dist/*.whl
}
