# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: Bruno Pagani <archange@archlinux.org>
# Contributor: Andrzej Giniewicz <gginiu@gmail.com>

pkgname=python-scikit-learn
pkgver=1.5.0
pkgrel=2
pkgdesc='A set of python modules for machine learning and data mining'
arch=(x86_64 aarch64)
url='https://scikit-learn.org'
_url='https://github.com/scikit-learn/scikit-learn'
license=(BSD-3-Clause)
depends=(python-joblib
         python-numpy
         python-scipy
         python-threadpoolctl)
makedepends=(cython
             openmp
             python-{build,installer,wheel}
             meson-python)
optdepends=('python-matplotlib: plotting capabilities')
options=(!emptydirs)
_archive="${pkgname#python-}-$pkgver"
source=("$_url/archive/$pkgver/$_archive.tar.gz")
sha256sums=('cd2aac2b566c7e740d34aabb4737864c74ba33c29aad7101fbf1bab2931c02dc')

prepare() {
	cd $_archive
	sed -i -E \
		-e '/setuptools/s/<[0-9.]+//' \
		-e '/numpy/d' \
		-e '/Cython/s/,<3.0//' \
		pyproject.toml
}

build() {
	cd $_archive
	python -m build -wn
}

package() {
	cd $_archive
	python -m installer -d "$pkgdir" dist/*.whl
	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" COPYING
	# See FS#49651
	install -d "$pkgdir/usr/share/doc/$pkgname/"
	cp -r doc/tutorial "$pkgdir/usr/share/doc/$pkgname/tutorial"
}
