# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=pifpaf
pkgver=3.1.5
_commit=d5e33872c3c2ef3067da6e1150c3f050f4a7b620
pkgrel=8
pkgdesc='Suite of tools and fixtures to manage daemons for testing'
arch=('any')
license=('Apache')
url='https://github.com/jd/pifpaf'
# setuptools is required for entry points queried by pkg_resources
depends=('python-daiquiri' 'python-click' 'python-pbr' 'python-jinja' 'python-fixtures'
         'python-psutil' 'python-xattr' 'python-setuptools')
provides=("python-pifpaf=$pkgver")
conflicts=('python-pifpaf')
replaces=('python-pifpaf')
makedepends=('git')
checkdepends=('python-testrepository' 'python-requests' 'python-testtools' 'python-oslotest'
              'memcached' 'percona-server' 'percona-server-clients' 'postgresql' 'redis'
              'consul' 'couchdb' 'httpbin' 'rabbitmq')
source=("git+https://github.com/jd/pifpaf.git#commit=$_commit")
sha512sums=('SKIP')

build() {
  cd pifpaf
  python setup.py build
}

check() {
  # Hack entry points by installing it

  cd pifpaf
  python setup.py install --root="$PWD/tmp_install" --optimize=1
  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  # TODO: fix test failures
  PYTHONPATH="$PWD/tmp_install/$site_packages" \
  PATH="$PWD/tmp_install/usr/bin:$PATH" \
  python setup.py testr || echo "Tests failed"
}

package() {
  cd pifpaf
  python setup.py install --root="$pkgdir" --optimize=1
}
