# Maintainer: Felix Yan <felixonmars@archlinux.org>

_gemname=async-http-cache
pkgname="ruby-${_gemname}"
pkgver=0.4.6
pkgrel=1
pkgdesc='Standard-compliant cache for async-http'
arch=(any)
url='https://github.com/socketry/async-http-cache'
license=(MIT)
depends=(
  ruby
  ruby-async-http
)
checkdepends=(
  ruby-bake
  ruby-bake-test
  ruby-bake-test-external
  ruby-bundler
  ruby-covered
  ruby-decode
  ruby-sus
  ruby-sus-fixtures-async-http
  ruby-sus-fixtures-console
)
options=(!emptydirs)
source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz"
  "82cb622ec5fa65efea08075f5d4a05bdc84ee73a.patch")
sha512sums=('5307d221c646236381351169be47e8473e03fba4ae8bdcf5cfc13dd8898eb26c9f66c231337b5d561cda10416aafa06e423ff24c8f2f78f6c7d2c4ee63aa93f9'
            '5e94be2d0dbd3c70ba02300cefddfeea0d310999ab416a0871511741fa00fe10fbc8401544cec8b9546aac1c31d021f778be84cb2a08066b9cef3ee6058f2ea1')
b2sums=('585cf6730d45170ae386b04cbc797e23644f2b8100b784f7e5ec1c70e11b51534cb8caf95d1706e860700335044ad0f0c08a73ddd5ba3d4a560c2bdf42371b29'
        '9e53897e47fb8ae2c834d323bc91fb965074785053c9d68a605e06b036ab48c2375d1e3f1990e9fa66285009312bd23c6cac0976dbe3ea67b68274171f8e4f5e')

prepare() {
  cd async-http-cache-$pkgver

  patch -Np1 -i "${srcdir}/82cb622ec5fa65efea08075f5d4a05bdc84ee73a.patch"

  sed -r -e 's|~>|>=|g' -e '/signing_key/d' -i async-http-cache.gemspec
  sed --in-place \
    --expression '/group :maintenance/,/end/d' \
    --expression '/rubocop/d' \
    gems.rb
}

build() {
  cd async-http-cache-$pkgver

  local _gemdir="$(gem env gemdir)"

  gem build --verbose "${_gemname}.gemspec"

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "tmp_install${_gemdir}" \
    --bindir "tmp_install/usr/bin" \
    "${_gemname}-${pkgver}.gem"

  # remove unreproducible files
  rm --force --recursive --verbose \
    "tmp_install${_gemdir}/cache/" \
    "tmp_install${_gemdir}/gems/${_gemname}-${pkgver}/vendor/" \
    "tmp_install${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"

  find "tmp_install${_gemdir}/gems/" \
    -type f \
    \( \
      -iname "*.o" -o \
      -iname "*.c" -o \
      -iname "*.so" -o \
      -iname "*.time" -o \
      -iname "gem.build_complete" -o \
      -iname "Makefile" \
    \) \
    -delete

  find "tmp_install${_gemdir}/extensions/" \
    -type f \
    \( \
      -iname "mkmf.log" -o \
      -iname "gem_make.out" \
    \) \
    -delete
}

check() {
  cd async-http-cache-$pkgver

  local _gemdir="$(gem env gemdir)"

  GEM_HOME="tmp_install/$_gemdir" bake test
}

package() {
  cd async-http-cache-$pkgver

  cp --archive --verbose tmp_install/* "$pkgdir"/

  install --verbose -D --mode=0644 license* --target-directory "${pkgdir}/usr/share/licenses/${pkgname}"
  install --verbose -D --mode=0644 *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}
