# Maintainer: Pierre Schmitz <pierre@archlinux.de>

pkgname=run-parts
pkgver=5.17
pkgrel=1
pkgdesc='run scripts or programs in a directory'
arch=('x86_64' 'aarch64')
url='https://packages.qa.debian.org/d/debianutils.html'
license=('GPL')
depends=('glibc')
makedepends=('po4a' 'git')
_gitcommit='baf12e98a02883d1b76081e32f2185ee3497570b'
source=("debianutils-$pkgver::git+https://salsa.debian.org/debian/debianutils#commit=${_gitcommit}")
sha256sums=('b6193a3bc717fdef2ce6ef4d4eda524480cf9aa0bee6ee696e5cbd21de30e1e5')

prepare() {
  cd "$srcdir/debianutils-${pkgver}"

  autoreconf -fi
}

build() {
  cd "$srcdir/debianutils-${pkgver}"

  ./configure --prefix=/usr
  make run-parts
  make -C po4a
}

package() {
  cd "$srcdir/debianutils-${pkgver}"

  install -D -m0755 run-parts "${pkgdir}/usr/bin/run-parts"
  install -D -m0644 run-parts.8 "${pkgdir}/usr/share/man/man8/run-parts.8"
  for MAN in $(find po4a/ -name run-parts.8); do
   install -D -m644  "${MAN}" "$pkgdir/usr/share/man/${MAN:5:2}/man8/run-parts.8"
  done
}
