# Maintainer: Tim Meusel <tim@bastelfreak.de>
# Contributor: Christian Rebischke <chris.rebischke@archlinux.org>

_gemname='hashdiff'
pkgname="ruby-${_gemname}"
pkgver=1.1.0
pkgrel=1
pkgdesc='Library to compute the smallest difference between two hashes'
arch=('any')
url="https://github.com/liufengyun/${_gemname}"
license=('MIT')
makedepends=('ruby-rdoc' 'ruby-bundler')
checkdepends=('ruby-rake' 'ruby-rspec')
depends=('ruby')
options=(!emptydirs)
source=("${url}/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz")
sha512sums=('8f39b7cffd60cf04c2485665b1d0a27d5fde64e7bf4ddc9f00bedbe9d6aa868139236082551d04d540d9309b8ce7bdb42ca95324f9393e47e9b98c0308049cce')

prepare() {
  cd "${srcdir}/${_gemname}-${pkgver}"

  # use `find` instead of `git`, since we have a tar ball and not a VCS repository
  sed --in-place 's/git ls-files.*`/find`/g' "${_gemname}.gemspec"
  sed --in-place '/test_files/d' "${_gemname}.gemspec"

  # rubocop would test if the code works on a legay ruby platform
  sed --in-place '/rubocop/d' Rakefile
  sed --in-place '/RuboCop/d' Rakefile

  # loading bundler isn't required and often triggers side effects
  # because it wants *all* gems from gemspec + Gemfile
  sed --in-place '/Bundler/d' Rakefile
  sed --in-place '/Bundler/d' Rakefile

  # the project has a few dependencies for releasing
  sed --in-place '/bluecloth/d' "${_gemname}.gemspec"
  sed --in-place '/rubocop/d' "${_gemname}.gemspec"
  sed --in-place '/yard/d' "${_gemname}.gemspec"
}

build() {
  cd "${srcdir}/${_gemname}-${pkgver}"
  gem build "${_gemname}.gemspec"
}

check() {
  cd "${srcdir}/${_gemname}-${pkgver}"
  rake spec
}

package() {
  cd "${srcdir}/${_gemname}-${pkgver}"
  local _gemdir="$(gem env gemdir)"
  gem install --verbose --ignore-dependencies --no-user-install --install-dir "${pkgdir}/${_gemdir}" --bindir "${pkgdir}/usr/bin" "${_gemname}-${pkgver}.gem"

  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"

  rm -rf "${pkgdir}/${_gemdir}/cache"
}

# vim: ts=2 sw=2 et:
