# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Ralf Schmitt <ralf@systemexit.de>

pkgname=python-gevent
pkgver=24.2.1
pkgrel=2
arch=('x86_64' 'aarch64')
pkgdesc="Python network library that uses greenlet and libev for easy and scalable concurrency"
license=("MIT")
url="http://www.gevent.org/"
depends=('c-ares' 'libev' 'python-greenlet' 'python-setuptools' 'python-zope-event' 'python-zope-interface')
makedepends=('cython')
checkdepends=('lsof' 'python-perf' 'python-objgraph' 'python-dnspython' 'python-requests')
source=("$pkgname-$pkgver.tar.gz::https://github.com/gevent/gevent/archive/$pkgver.tar.gz")
sha512sums=('bfcaf437ba4d6565bd5904dc0d45df035fe9b4bd572f8bf509d1ec9994ae812317bdea9e948b57f47435752bffebb7cc925dbf060db5d56c5c05b29cbd061639')

export GEVENTSETUP_EMBED=0

build() {
  cd gevent-$pkgver
  python setup.py build
}

check() {
  (
    cd gevent-$pkgver
    python -m venv "$srcdir/pyvenv" --system-site-packages
    . "$srcdir/pyvenv/bin/activate"
    local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
    export PYTHONPATH="$PYTHONPATH:/$site_packages"
    python setup.py install
    python -m gevent.tests
  ) || echo "Tests failed"
}

package() {
  cd gevent-$pkgver
  python setup.py install -O1 --root="$pkgdir"
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
}
