# Maintainer: Alexander Baldeck <alexander@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

_pkgbasename=libxau
pkgname=lib32-$_pkgbasename
pkgver=1.0.11
pkgrel=1
pkgdesc="X11 authorisation library (32-bit)"
arch=(x86_64)
url="https://xorg.freedesktop.org/"
license=('custom')
depends=('lib32-glibc' $_pkgbasename)
makedepends=('pkgconf' 'xorgproto')
provides=('libXau.so')
options=('debug')
source=(${url}/releases/individual/lib/libXau-${pkgver}.tar.xz)
sha1sums=('0cf6d853fce4dc72d61c253d096408a313f1163b')
sha256sums=('f3fa3282f5570c3f6bd620244438dbfbdd580fc80f02f549587a0f8ab329bbeb')

build() {
  cd "${srcdir}/libXau-${pkgver}"

  export CC="gcc -m32"
  export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"

  ./configure --prefix=/usr --sysconfdir=/etc --libdir=/usr/lib32
  make
}

package() {
  cd "${srcdir}/libXau-${pkgver}"

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"/usr/{include,share}

  mkdir -p "$pkgdir/usr/share/licenses"
  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}
