# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Justin "juster" Davis <jrcd83@gmail.com>
# Generator : pbjam 0.01

pkgname=perl-http-message
pkgver=7.02
pkgrel=1
pkgdesc="HTTP style messages"
arch=(any)
url='https://search.cpan.org/dist/HTTP-Message'
license=('Artistic-1.0-Perl OR GPL-1.0-or-later')
options=(!emptydirs)
depends=(perl perl-clone perl-encode-locale perl-http-date perl-io-html
         perl-lwp-mediatypes perl-uri)
checkdepends=(perl-io-compress-brotli perl-test-needs perl-try-tiny)
conflicts=('perl-libwww<6')
source=("https://github.com/libwww-perl/HTTP-Message/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('c7f02dcb1ee6a679981345c70a41903059e4ddd1266191cfb287a957b3be7011f5d423ee1019d22c01f7eb79516ef9d41be4e3a34b67f097c34f8c6e6e655e06')

build() {
  cd HTTP-Message-$pkgver
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd HTTP-Message-$pkgver
  make test
}

package() {
  cd HTTP-Message-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et:
