# Maintainer: Sébastien "Seblu" Luttringer <seblu@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=less
pkgver=704
pkgrel=1
epoch=1
pkgdesc='A terminal based program for viewing text files'
license=('GPL-3.0-or-later OR LicenseRef-Less')
arch=('x86_64' 'aarch64')
url='https://www.greenwoodsoftware.com/less/'
depends=(
  glibc
  ncurses 
  pcre2
)
makedepends=(
  git
)
validpgpkeys=('AE27252BD6846E7D6EAE1DD6F153A7C833235259') # Mark Nudelman
source=(
  https://www.greenwoodsoftware.com/$pkgname/$pkgname-$pkgver.tar.gz
  $pkgname-$pkgver.tar.gz.sig::https://www.greenwoodsoftware.com/$pkgname/$pkgname-$pkgver.sig
)
b2sums=('490b5ea9006cec85b8a44f19bfc47f99da7394664e4dc4ed37fb9610c42d9fbe206a702540aaa04fe9b3320e0672522fb740ad189c835aa5a4580da4175fae71'
        'SKIP')

prepare() {
  cd $pkgname-$pkgver
  # apply patch from the source array (should be a pacman feature)
  local src
  for src in "${source[@]}"; do
    src="${src%%::*}"
    src="${src##*/}"
    [[ $src = *.patch ]] || continue
    echo "Applying patch $src..."
    # TODO: reactivate when dropping the git exclude patch patch -Np1 < "../$src"
    git apply --exclude NEWS --exclude version.c "../$src"
  done
}

build() {
  cd $pkgname-$pkgver
  sh configure --prefix=/usr --libexecdir=/usr/lib --sysconfdir=/etc --with-regex=pcre2
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 {,"$pkgdir"/usr/share/licenses/$pkgname/}LICENSE
}

# vim:set ts=2 sw=2 et:
