# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: Eric Lehmann <katyl@katyl.info>
# Contributor: Thomas Fanninger <thomas@fanninger.at>
# Contributor: ultraviolet <ultravioletnanokitty@gmail.com>
# Contributor: Pablo Lezeta <prflr88@gmail.com>

pkgname=iio-sensor-proxy
pkgver=3.9
pkgrel=1
pkgdesc='IIO accelerometer sensor to input device proxy'
arch=('x86_64' 'aarch64')
url='https://gitlab.freedesktop.org/hadess/iio-sensor-proxy/'
license=('GPL-3.0-only')
depends=(glib2
         glibc
         libgcc
         libgudev
         libssc
         polkit)
makedepends=(git
             meson)
checkdepends=(python-dbusmock
              python-gobject
              python-psutil
              umockdev)
source=(git+https://gitlab.freedesktop.org/hadess/iio-sensor-proxy#tag=$pkgver)
sha512sums=('6667d70fd01285f9b48fa2dfc829e3186773457c4430f8373a8e0b4e25b0f31ee2780a3766206a13bcfb2721ce10978713b8bf61c844da027c444a754f910473')

build() {
  arch-meson build $pkgname \
    -Dsystemdsystemunitdir=/usr/lib/systemd/system \
    -Dudevrulesdir=/usr/lib/udev/rules.d \
    -Dsysconfdir=/usr/share
  meson compile -C build
}

check() {
  meson test -C build
}

package() {
  meson install -C build --destdir="$pkgdir"
}
