# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=cryptohash-md5
pkgname=haskell-cryptohash-md5
pkgver=0.11.101.0
pkgrel=245
pkgdesc="Fast, pure and practical MD5 implementation"
url="https://github.com/hvr/cryptohash-md5"
license=("BSD")
arch=('x86_64' 'aarch64')
depends=('ghc-libs')
makedepends=('ghc' 'uusi' 'haskell-base16-bytestring' 'haskell-puremd5' 'haskell-tasty'
             'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha512sums=('6116b384e76927aed06748fac6088280d1ecc7eb5886692c287e971761b98960657b106ba8a700bd0c5b2e552797079e143836af3463acd75bbac207633867a4')

prepare() {
    cd $_hkgname-$pkgver
    uusi -u base -u tasty -u tasty-quickcheck
}

build() {
    cd $_hkgname-$pkgver

    runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver

    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
