# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: tobias <tobias@arhlinux.org>

pkgname=exiv2
pkgver=0.28.8
pkgrel=2
pkgdesc="Exif, Iptc and XMP metadata manipulation library and tools"
url="https://exiv2.org"
arch=('x86_64' 'aarch64')
license=('GPL-2.0-or-later')
depends=(brotli libbrotlidec.so
         curl
         expat libexpat.so
         gettext
         glibc # libc.so libm.so
         libcurl.so
         libgcc # libgcc_s.so
         libinih libINIReader.so
         libstdc++ # libstdc++.so
         zlib libz.so)
makedepends=('git' 'cmake' 'gtest' 'ninja')
checkdepends=('python')
provides=('libexiv2.so')
source=(git+https://github.com/Exiv2/exiv2#tag=v$pkgver)
sha512sums=('f8303d2121c602a89afee5aca059f7d8635da13c0fad786556e01d0ed009bc4cfd45a0d5f52a49b7992a2f8170ddfc2e9f6040419200890af66f2e0004a1324c')
b2sums=('86c65a80aa45c0dfa97e68de475b0bc661a34d97d3ab302fb233077e139c1f3b3ecd8bf63679b728359cb1cc8a30f05ca91795bc5dc37770b810f7f14d3d4ce6')

build() {
  cd ${pkgname}
  cmake -B build \
    -GNinja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DEXIV2_BUILD_SAMPLES=ON \
    -DEXIV2_BUILD_UNIT_TESTS=ON \
    -DEXIV2_ENABLE_VIDEO=ON \
    -DEXIV2_ENABLE_NLS=ON \
    -DEXIV2_ENABLE_XMP=ON \
    -DEXIV2_ENABLE_CURL=ON \
    -DEXIV2_ENABLE_WEBREADY=ON \
    -DEXIV2_ENABLE_BMFF=ON
  ninja -C build
}

check() {
  cd ${pkgname}
  LD_LIBRARY_PATH="$PWD"/build/lib \
  ninja -C build test
}

package() {
  cd ${pkgname}
  # remove samples instal which are only needed for unit tests
  sed '/samples\/cmake_install.cmake/d' -i build/cmake_install.cmake
  DESTDIR="${pkgdir}" ninja -C build install
}

# vim: ts=2 sw=2 et:
