# Maintainer: Evangelos Foutras <foutrelis@archlinux.org>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>

pkgname=compiler-rt
pkgver=22.1.3
pkgrel=1
pkgdesc="Compiler runtime libraries for clang"
arch=('x86_64' 'aarch64')
url="https://compiler-rt.llvm.org/"
license=('Apache-2.0 WITH LLVM-exception')
depends=('glibc' 'libgcc' 'libstdc++')
makedepends=('llvm' 'cmake' 'ninja' 'python')
# Build 32-bit compiler-rt libraries on x86_64 (FS#41911)
makedepends_x86_64=('lib32-gcc-libs')
options=('staticlibs' '!lto')
_source_base=https://github.com/llvm/llvm-project/releases/download/llvmorg-$pkgver
source=($_source_base/llvm-project-$pkgver.src.tar.xz{,.sig})
source_aarch64=(https://github.com/llvm/llvm-project/commit/ea9f8b77467fdbfab0d5bb3342e97de6b54e4e2d.patch)
sha256sums=('2488c33a959eafba1c44f253e5bbe7ac958eb53fa626298a3a5f4b87373767cd'
            'SKIP')
sha256sums_aarch64=('ca4dd6084c8e822846bbe6f6eb54ab8cd8ca413ff360dfd4df45d913e415c011')

validpgpkeys=('474E22316ABF4785A88C6E8EA2C794A986419D8A'  # Tom Stellard <tstellar@redhat.com>
              'D574BD5D1D0E98895E3BF90044F2485E45D59042'  # Tobias Hieta <tobias@hieta.se>
              'FFB3368980F3E6BB5737145A316C56D064CACBA5'  # Douglas Yung <douglas.yung@sony.com>
              '71046D1E9C6656BDD61171873E83BABF4A4F9E85'  # Cullen Rhodes <cullen.rhodes@arm.com>
)

prepare() {
  pushd llvm-project-$pkgver.src
  [[ $CARCH = 'aarch64' ]] && patch -p1 -i "${srcdir}"/ea9f8b77467fdbfab0d5bb3342e97de6b54e4e2d.patch
  popd

  cd llvm-project-$pkgver.src/compiler-rt
  mkdir -p build
}

build() {
  cd llvm-project-$pkgver.src/compiler-rt/build

  local cmake_args=(
    -G Ninja
    -DCMAKE_BUILD_TYPE=Release
    -DCMAKE_INSTALL_PREFIX=/usr
    -DCMAKE_SKIP_RPATH=ON
    -DCOMPILER_RT_INSTALL_PATH=/usr/lib/clang/${pkgver%%.*}
  )
  cmake .. "${cmake_args[@]}"
  ninja
}

package() {
  cd llvm-project-$pkgver.src/compiler-rt/build

  DESTDIR="$pkgdir" ninja install
  install -Dm644 "$srcdir/llvm-project-$pkgver.src/compiler-rt/LICENSE.TXT" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et:
