# Maintainer: Anatol Pomozov
# Maintainer: Carl Smedstad <carsme@archlinux.org>

pkgname=s2n-tls
pkgver=1.7.1
pkgrel=1
pkgdesc='A C99 implementation of the TLS/SSL protocols that is designed to be simple, small, fast, and with security as a priority'
arch=(x86_64 aarch64)
url='https://github.com/aws/s2n-tls'
license=(Apache-2.0)
depends=(
  glibc
  libgcc
  openssl
)
makedepends=(cmake)
provides=(s2n) # upstream renamed the project from s2n to s2n-tls
conflicts=(s2n)
replaces=(s2n)
source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz")
b2sums=('0b726a5c56fc9e709189b944b7ea803a02a1e2746b21a75388d1c6ed9c28bc3ba0ef21f2a62e833cae64fc2d9fb445f0ab571bb91d49585ac5b25cc9adac34db')

build() {
  cd $pkgname-$pkgver
  cmake -S . -B build \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -Wno-dev \
    -DBUILD_SHARED_LIBS=ON
  cmake --build build
}

check() {
  cd $pkgname-$pkgver
  ctest --test-dir build --output-on-failure \
    -E s2n_override_openssl_random_test
}

package() {
  cd $pkgname-$pkgver
  DESTDIR="$pkgdir" cmake --install build
}
