# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=perl-libwww
pkgver=6.82
pkgrel=1
pkgdesc='The World-Wide Web library for Perl'
arch=(any)
url='https://metacpan.org/release/libwww-perl'
license=('GPL-1.0-or-later OR Artistic-1.0-Perl')
depends=(
  perl
  perl-encode-locale
  perl-file-listing
  perl-html-parser
  perl-http-cookies
  perl-http-daemon
  perl-http-cookiejar
  perl-http-date
  perl-http-negotiate
  perl-lwp-mediatypes
  perl-net-http
  perl-try-tiny
  perl-uri
  perl-www-robotrules
)
optdepends=('perl-lwp-protocol-https: for https:// url schemes')
checkdepends=(
  perl-test-fatal
  perl-test-needs
  perl-test-requiresinternet
)
options=(!emptydirs)
source=(https://cpan.metacpan.org/authors/id/O/OA/OALDERS/libwww-perl-$pkgver.tar.gz)
sha512sums=('2d090456f1e6808de7712b81d9d88da32edfaf1e841ec7669d12e93349159d7fd472155798a4bf03d9ac7fac45d93da9c680197fb2ad4482fa0ebbbabb82c2cd')
b2sums=('0f49d1563b6e86b79dc83272936db5e2682f852170a029c9dfb9cf456b499bb0f4f653f7a8da7baf0eb82d904f7b149d7fec8e889536a8771dd005aa3fad71a2')

build() {
  cd "libwww-perl-$pkgver"

  unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  perl Makefile.PL
  make
}

check()  {
  cd "libwww-perl-$pkgver"

  unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1
  make test
}

package() {
  cd "libwww-perl-$pkgver"

  unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
  make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
}
