# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Laurent Carlier <lordheavym@gmail.com>

pkgname=vulkan-tools
pkgver=1.4.341.0
pkgrel=2
pkgdesc="Vulkan tools and utilities"
url="https://www.vulkan.org/"
arch=(x86_64 aarch64)
license=(Apache-2.0)
depends=(
  glibc
  libgcc
  libstdc++
  libx11
  libxcb
  vulkan-icd-loader
  wayland
)
makedepends=(
  cmake
  git
  glslang
  libxrandr
  ninja
  python
  spirv-tools
  volk
  vulkan-headers
  wayland-protocols
)
groups=(vulkan-devel)
source=("git+https://github.com/KhronosGroup/Vulkan-Tools#tag=vulkan-sdk-$pkgver")
b2sums=('8cbd8200660bdd5bf6eb5c601820b288a299afeb69464a43c5d04f68a87a4cf5d0a090be4f5c6e04f2f2e54eeaa0fecd3cfa52b1a9c2ce566f9f99b555eed8e6')

build() {
  local cmake_options=(
    -D BUILD_ICD=OFF
    -D CMAKE_BUILD_TYPE=Release
    -D CMAKE_INSTALL_PREFIX=/usr
    -D CMAKE_INSTALL_SYSCONFDIR=/etc
    -D CMAKE_SKIP_INSTALL_RPATH=ON
  )

  cmake -S Vulkan-Tools -B build -G Ninja "${cmake_options[@]}"
  cmake --build build
}

check() {
  ctest --test-dir build --output-on-failure --stop-on-failure
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}

# vim:set sw=2 sts=-1 et:
