# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Maintainer: David Runge <dvzrv@archlinux.org>
# Maintainer: Chistian Heusel <gromit@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>

pkgname=libid3tag
pkgver=0.16.4
pkgrel=1
pkgdesc="ID3 tag manipulation library"
arch=(x86_64 aarch64)
url="https://codeberg.org/tenacityteam/libid3tag"
license=("GPL-2.0-or-later")
depends=(glibc zlib)
makedepends=(cmake gperf)
provides=(libid3tag.so)
source=(
  $pkgname-$pkgver.tar.gz::https://codeberg.org/tenacityteam/libid3tag/archive/$pkgver.tar.gz
)
sha512sums=('7ea09cc9a2047799d3f8a0dceebc9822ea1625f045c637a65dfa85364b17556b5dccb8b6cc9a8991e45f2b8d35d2b4f0fd084144afb40738d99bc0a60479223c')
b2sums=('ca750614c98f8b75d9dd7541a4b4629391f2705f9373b26c035843085bb50f9cfc156e2f74e6df2bb7f24db69e0add2907cb25a278c5b86cee4bccb10cb58fbb')

build() {
  local cmake_options=(
    -B build
    -D CMAKE_BUILD_TYPE=None
    -D CMAKE_INSTALL_PREFIX=/usr
    -S $pkgname
    -W no-dev
  )

  cmake "${cmake_options[@]}"
  cmake --build build --verbose
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}
