# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=gperf
pkgver=3.3
pkgrel=2
pkgdesc="Perfect hash function generator"
arch=('x86_64' 'aarch64')
url="https://www.gnu.org/software/gperf/"
license=('GPL-3.0-or-later')
depends=(
  'glibc'
  'libgcc'
  'libstdc++'
)
options=('!makeflags')
source=("https://ftpmirror.gnu.org/gnu/gperf/${pkgname}-${pkgver}.tar.gz"{,.sig})
b2sums=('76fd532c4443d27031c8b2dbceaa985d0d3eed8d66f2ba2d128d027ecec0175717ab1468236b0b0405445e7457076a802458e326d5023ce28869e478ca622fa9'
        'SKIP')
validpgpkeys=(
  'EDEB87A500CC0A211677FBFD93C08C88471097CD' # Marcel Schaible <marcel.schaible@studium.fernuni-hagen.de>
  'E0FFBD975397F77A32AB76ECB6301D9E1BBEAC08' # Bruno Haible (Free Software Development) <bruno@clisp.org>
)

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
    --docdir=/usr/share/gperf/doc/
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}
