# Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>

_gemname='rake-compiler-dock'
pkgname="ruby-${_gemname}"
pkgver=1.11.1
pkgrel=1
pkgdesc='Easy to use and reliable cross compiler environment for building Windows, Linux, Mac and JRuby binary gems'
arch=('any')
url='https://github.com/rake-compiler/rake-compiler-dock'
license=('MIT')
options=('!emptydirs')
depends=(
  ruby
)
makedepends=(
  ruby-bundler
  ruby-rake
  ruby-test-unit
)
checkdepends=(
  ruby-erb
)
source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha512sums=('e4eaad99a12c22616b1e067e77f6256b95896b67cb6410382ebcfaf5d007df503cb24ac7f886fbb693763efb39a0cb32d3bab43b844319d60fa89bf09027d440')
b2sums=('c2fce177f00184792da1963763d813cef415e22ff8fbc3f67bfe7d4b2f645e35450f2c69565543dae8024d0f13e263c738230e94c0408116008cd82f13aa8188')

prepare() {
  cd "${_gemname}-${pkgver}"

  # update gemspec/Gemfile to allow newer version of the dependencies
  sed --in-place --regexp-extended 's|~>|>=|g' "${_gemname}.gemspec"

  # we built based on a tar archive, not a git repo
  sed --in-place 's/git ls-files -z/find -print0/' "${_gemname}.gemspec"

  # remove tests which need docker
  rm --verbose test/test_environment_variables.rb
}

build() {
  cd "${_gemname}-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  gem build --verbose "${_gemname}.gemspec"

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "tmp_install${_gemdir}" \
    --bindir "tmp_install/usr/bin" \
    "${_gemname}-${pkgver}.gem"

  # remove unreproducible files
  rm --force --recursive --verbose \
    "tmp_install${_gemdir}/cache/" \
    "tmp_install${_gemdir}/gems/${_gemname}-${pkgver}/vendor/" \
    "tmp_install${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"

  find "tmp_install${_gemdir}/gems/" \
    -type f \
    \( \
      -iname "*.o" -o \
      -iname "*.c" -o \
      -iname "*.so" -o \
      -iname "*.time" -o \
      -iname "gem.build_complete" -o \
      -iname "Makefile" \
    \) \
    -delete

  find "tmp_install${_gemdir}/extensions/" \
    -type f \
    \( \
      -iname "mkmf.log" -o \
      -iname "gem_make.out" \
    \) \
    -delete
}

check() {
  cd "${_gemname}-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  GEM_HOME="tmp_install${_gemdir}" TEST_PLATFORM=x86_64-linux-gnu rake test
}

package() {
  cd "${_gemname}-${pkgver}"

  cp --archive --verbose tmp_install/* "${pkgdir}"

  install --verbose -D --mode=0644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install --verbose -D --mode=0644 *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}
