# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>

pkgname=libngtcp2
pkgver=1.5.0
pkgrel=1
pkgdesc='Implementation of IETF QUIC protocol'
url='https://github.com/ngtcp2/ngtcp2'
arch=('x86_64' 'aarch64')
license=('MIT')
depends=('glibc')
makedepends=('brotli')
provides=('libngtcp2.so')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/ngtcp2/ngtcp2/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('7545d489e91749d30e337e32cfafb002afcf289796b1799fa451650c6c0fd32e')
b2sums=('30497c9af15900ed4f493e8c9485f4516d425b8df30a45b240348ea55e85d652d2345201a97ec93dbc892154d2af28e94fe90c7a6f4bf3678e8fa442c12b61f7')

prepare() {
  cd ngtcp2-${pkgver}
  autoreconf -i
}

build() {
  cd ngtcp2-${pkgver}
  # add --with-openssl after quic was released in openssl mainline
  ./configure \
    --prefix=/usr \
    --with-libbrotlienc \
    --with-libbrotlidec
  make
}

package() {
  cd ngtcp2-${pkgver}/lib
  make DESTDIR="${pkgdir}" install
  install -Dm644 ../COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et:
