# Based on upstream v.76.1-1
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Art Gramlich <art@gramlich-net.com>
# Contributor: Denis Pynkin <denis.pynkin@collabora.com>

pkgbase=icu
pkgname=('icu'
         'icu-libs')
pkgver=76.1
pkgrel=2
pkgdesc="International Components for Unicode library"
arch=(aarch64)
url="https://icu.unicode.org"
license=('LicenseRef-Unicode-3.0'
         'BSD-2-Clause'
         'BSD-3-Clause'
         'NAIST-2003')
depends=('gcc-libs' 'glibc' 'sh')
makedepends=('python')
source=(https://github.com/unicode-org/icu/releases/download/release-${pkgver//./-}/icu4c-${pkgver//./_}-src.tgz{,.asc}
        ICU-22132.patch)
# https://github.com/unicode-org/icu/releases/download/release-76-1/SHASUM512.txt
sha512sums=('b702ab62fb37a1574d5f4a768326d0f8fa30d9db5b015605b5f8215b5d8547f83d84880c586d3dcc7b6c76f8d47ef34e04b0f51baa55908f737024dd79a42a6c'
            'SKIP'
            '1178062ccfcf7ecc698c64132b3612e73f9c4b0bbfaa668ae2039f3eb4cb2722d0b08a9f45b057da10def7a308d5c8d14c0c644892e7f11092c9cc488c850ab7')
validpgpkeys=('E52F07877A5805F9AF4AB0ACD46C5610D06E7001') # ICU Release Robot <icu-robot@unicode.org>

prepare() {
  cd icu/source
  # Required fix for thunderbird 115 to show Calendar and sidebar properly
  # https://bugzilla.mozilla.org/show_bug.cgi?id=1843007
  # https://unicode-org.atlassian.net/browse/ICU-22132
  patch -Np1 < "../../ICU-22132.patch"
}

build() {
  cd icu/source
  ./configure --prefix=/usr \
	--sysconfdir=/etc \
	--mandir=/usr/share/man \
	--sbindir=/usr/bin
  make
}

check() {
  cd icu/source
  make check
}

package_icu() {
  depends=("icu-libs=${pkgver}")
  cd icu/source
  make DESTDIR="${pkgdir}" install

  # Move out runtime libs from icu package
  mkdir -p "${pkgdir}"/../"${pkgname}-libs"/usr/lib
  mv -vf "${pkgdir}"/usr/lib/*.so.* "${pkgdir}"/../"${pkgname}-libs"/usr/lib/

  # Install license
  install -Dm644 ../LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}

package_icu-libs() {
  provides=(libicu{data,i18n,io,test,tu,uc}.so=${pkgver%.*})

  # Install license
  install -Dm644 ../LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}-${pkgver}/LICENSE
}
