# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Johannes Löthberg <johannes@kyriasis.com>
# Contributor: Piotr Gorski <lucjan.lucjanov@gmail.com>
# Contributor: Lucy <lucy@luz.lu>
# Contributor: Bartlomiej Piotrowski <nospam@bpiotrowski.pl>

pkgname=pkgconf
pkgver=2.4.3
pkgrel=1
pkgdesc="Package compiler and linker metadata toolkit"
url="https://gitea.treehouse.systems/ariadne/pkgconf"
license=(ISC)
arch=(x86_64 aarch64)
depends=(
  glibc
  sh
)
makedepends=(
  git
  meson
)
provides=(
  libpkgconf.so
  pkg-config
  pkgconfig
)
conflicts=(pkg-config)
replaces=(pkg-config)
source=(
  "git+$url#tag=pkgconf-$pkgver"
  {x86_64-pc,i686-pc,aarch64}-linux-gnu.personality
)
b2sums=('54fb510c563818199f1a5161cf5a2ba0fba70b09f4288a31ece936cf42197f5ee9cf2021733a927ae778a9bb1fa3dfbfbcba898826266c01b45b3f3154699db6'
        'c04583e19149c1035cb7777a59f0fbc4988b672d8e45105e33def3d0f9054464e33a400a3e7c7e8b99b334e4fe06aaa9d7e34662e806096d4374bd6b12d803db'
        '94c8fd12b5f33611fd6dbeae03b20e72bcf2937e764766e2633b2fd4c14925860d57eee234016c81b0563a47b112ac9ef4a8b3bb9fa3fc0dd266f355bc156c58'
	'827747f005d6a39010827670b7745d795ecbb0c45f564cc9954d151cd45dee113f24ed88a38c87e63d4ee4e8bab08349918adcaf2971ee14e334bd61679250b8')

prepare() {
  cd pkgconf
}

build() {
  local meson_options=(
    -D tests=disabled  # Tests need kyua
  )

  arch-meson pkgconf build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"

  local arches="x86_64-pc-linux-gnu i686-pc-linux-gnu"
  if [ "$CARCH" = aarch64 ]; then
    arches=aarch64-linux-gnu
  fi
  local p
  for p in $arches; do
    install -Dt "$pkgdir/usr/share/pkgconfig/personality.d" -m644 $p.personality
    ln -s pkgconf "$pkgdir/usr/bin/$p-pkg-config"
  done

  ln -s pkgconf "$pkgdir/usr/bin/pkg-config"
  ln -s pkgconf.1 "$pkgdir/usr/share/man/man1/pkg-config.1"

  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pkgconf/COPYING
}

# vim:set sw=2 sts=-1 et:
