# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=servant-server
pkgname=haskell-servant-server
pkgver=0.20
pkgrel=20
pkgdesc="A family of combinators for defining webservices APIs and serving them"
url="https://haskell-servant.readthedocs.org/"
license=("BSD")
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-base-compat' 'haskell-aeson' 'haskell-base64-bytestring'
         'haskell-constraints' 'haskell-http-api-data' 'haskell-http-media' 'haskell-http-types'
         'haskell-network-uri' 'haskell-monad-control' 'haskell-network' 'haskell-servant'
         'haskell-sop-core' 'haskell-string-conversions' 'haskell-resourcet' 'haskell-tagged'
         'haskell-transformers-base' 'haskell-wai' 'haskell-wai-app-static' 'haskell-warp'
         'haskell-word8')
makedepends=('ghc' 'haskell-hspec' 'haskell-hspec-wai' 'haskell-should-not-typecheck'
             'haskell-quickcheck' 'haskell-safe' 'haskell-wai-extra' 'haskell-temporary'
             'haskell-transformers-compat')
source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha512sums=('4db1d8f6b08ce3af835cbc6232951a1fc6d5d8a5d63a713b33c70be1d587f1c4e6825fa3893e27056ab4635477444ebb5479add8825e3e50473833e586c0c397')

build() {
    cd $_hkgname-$pkgver

    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver

    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
